小编给大家分享一下批处理如何计算天数，相信大部分人都还不怎么了解，因此分享这篇文章给大家参考一下，希望大家阅读完这篇文章后大有收获，下面让我们一起去了解一下吧！
创新互联-专业网站定制、快速模板网站建设、高性价比洪湖网站开发、企业建站全套包干低至880元,成熟完善的模板库,直接使用。一站式洪湖网站制作公司更省心,省钱,快速模板网站建设找我们，业务覆盖洪湖地区。费用合理售后完善，十载实体公司更值得信赖。
代码一、
:: DateDel2.bat - 删除指定路径下指定日数以前修改的文件
:: 注意事项：变量 tian 为指定日数，昨天为1，前天为2，依次类推
:: 核心算法：Ritchie Lawrence, updated 2002-08-13. Version 1.1
::
@echo off & setlocal ENABLEEXTENSIONS
call :Date2Day %date:~0,10% sdays
rem 下行的%tian%代表天数.
set /p tian= 请指定要追溯的天数：
set /a sdays-=tian
call :Day2Date %sdays% difdate
echo.&echo.
echo 指定的日期是： %date:~0,10%
echo.
echo %tian% 天前的日期是：%difdate%
echo.&pause
exit
:Date2Day
setlocal ENABLEEXTENSIONS
for /f "tokens=1-3 delims=/-, " %%a in ('echo/%1') do (
set yy=%%a & set mm=%%b & set dd=%%c
)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %2=%j%&goto :EOF
:Day2Date
setlocal ENABLEEXTENSIONS
set /a i=%1,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%-%mm%-%dd%&goto :EOF
代码二、
@echo off
:: 求N天前的日期
:: 思路：
:: 模拟手工运算，用日期数减去天数，差值为负时向高位借1。
:: 特点：
:: 代码简洁，容易理解，速度快慢取决于指定的天数大小
:: 日期可以带星期，但是，必须以年月日的顺序排列
:: 年份必须是四位，否则会出错
@echo off
:Main
cls
set day=%date%
set days=0
echo.&echo.
echo 指定的日期是：%day%
echo.
set /p input= 请指定要追溯的天数：
setlocal enabledelayedexpansion
:: 提取日期
for /f "tokens=1-3 delims=-/. " %%i in ("%day%") do (
set /a sy=%%i, sm=100%%j %% 100, sd=100%%k %% 100
)
set /a sd-=input
if %sd% leq 0 call :count
cls
echo.&echo.
echo 指定的日期是：%day%
echo.
set sm=0%sm%
set sd=0%sd%
echo %input% 天前的日期是：%sy%-%sm:~-2%-%sd:~-2%
pause>nul
goto Main
:count
set /a sm-=1
if !sm! equ 0 set /a sm=12, sy-=1
call :days
set /a sd+=days
if %sd% leq 0 goto count
goto :eof
:days
:: 获取指定月份的总天数
set /a leap="^!(sy %% 4) & ^!(^!(sy %% 100)) | ^!(sy %% 400)"
set /a max=28+leap
set num=0
set str=31 %max% 31 30 31 30 31 31 30 31 30 31
for %%i in (%str%) do (
set /a num+=1
if %sm% equ !num! set days=%%i&goto :eof
)
goto :eof
以上是“批处理如何计算天数”这篇文章的所有内容，感谢各位的阅读！相信大家都有了一定的了解，希望分享的内容对大家有所帮助，如果还想学习更多知识，欢迎关注创新互联行业资讯频道！
网站题目：批处理如何计算天数-创新互联
分享路径：
http://www.cdkjz.cn/article/pseeo.html
