exp方式导出：
创新互联公司专注于临猗企业网站建设,
成都响应式网站建设公司,
商城系统网站开发。临猗网站建设公司,为临猗等地区提供建站服务。全流程专业公司，专业设计，全程项目跟踪，
创新互联公司专业和态度为您提供的服务
1、根据日期自动生成 Oracle 备份文件
@echo off
echo 正在备份Oracle数据库，请稍等......
exp userid='用户名/密码@SID' file=D:\bak\res_%date:~0,4%%date:~5,2%%date:~8,2%.dmp log=D:\bak\res_%date:~0,4%%date:~5,2%%date:~8,2%.log owner=res
echo 任务完成！
2、根据日期时间分秒自动生成 Oracle 备份文件
@echo off
echo 正在备份Oracle数据库，请稍等......
exp userid='用户名/密码@SID' file=D:\bak\res_%date:~0,4%%date:~5,2%%date:~8,2%%Time:~0,2%%Time:~3,2%%Time:~6,2%.dmp log=D:\bak\res_%date:~0,4%%date:~5,2%%date:~8,2%%Time:~0,2%%Time:~3,2%%Time:~6,2%.log
echo 任务完成！
3、用exit结尾备份完后自动退出：
@echo off
echo ================================================
echo Windows环境下Oracle数据库的自动备份脚本
echo 1. 使用当前日期命名备份文件。
echo 2. 自动删除7天前的备份。
echo ================================================
::以“YYYYMMDD”格式取出当前时间。
set BACKUPDATE=%date:~0,4%%date:~5,2%%date:~8,2%%Time:~0,2%%Time:~3,2%%Time:~6,2%
::创建备份目录。
if not exist "D:\backup\data" mkdir D:\backup\data
if not exist "D:\backup\log" mkdir D:\backup\log
set DATADIR=D:\backup\data
set LOGDIR=D:\backup\log
exp userid='用户名/密码@SID' file=%DATADIR%\data_%BACKUPDATE%.dmp log=%LOGDIR%\log_%BACKUPDATE%.log
::删除7天前的备份。
forfiles /p "%DATADIR%" /s /m *.* /d -7 /c "cmd /c del @path"
forfiles /p "%LOGDIR%" /s /m *.* /d -7 /c "cmd /c del @path"
exit
注：如果有时我们写bat脚本执行时一闪而过，无法排错；那么我可以在脚本的最后加个pause(如上面的脚本可以把exit换成pause),用pause结尾执行完后，会提示按任意键来继续或退出，这样我就能知道是什么报错。
expdp方法导出：
用exit结尾备份完后自动退出：
@echo off
echo ================================================
echo Windows环境下Oracle数据库的自动备份脚本
echo 1. 使用当前日期命名备份文件。
echo 2. 自动删除10天前的备份。
echo 3.使用expdb命令导出需要先在数据库中创建备份文件存贮目录，sql如下:
echo create directory backdir as 'D:\backup\data';
echo ================================================
::以“YYYYMMDD”格式取出当前时间。
set BACKUPDATE=%date:~0,4%%date:~5,2%%date:~8,2%%Time:~0,2%%Time:~3,2%%Time:~6,2%
::设置用户名、密码和sid。
set bakdbname=app
set bakdbpasswd=123
set sid=orcl
set dumpbame=appbak
set bakdbhome=D:\backup\data
::创建备份目录。
if not exist "D:\backup\data" mkdir D:\backup\data
::expdp备份
expdp %bakdbname%/%bakdbpasswd%@%sid% directory=backdir dumpfile=%dumpbame%_%BACKUPDATE%.dmp logfile=%dumpbame%_%BACKUPDATE%.log
::切换目录
d:
cd %bakdbhome%
::调用rar进行压缩
::方法一winrar把log、dmp文件压缩成zip，不保留原始文件log,dmp文件（任选一种）
"C:\Program Files\WinRAR\Rar" a -m5 -dw %dumpbame%_%BACKUPDATE%".zip" %dumpbame%_%BACKUPDATE%.DMP
::方法二用winrar把log、dmp文件压缩成zip并保留原始文件log，dmp文件（任选一种）,去掉dw这个参数
"C:\Program Files\WinRAR\WinRAR.exe" a -m5 %dumpbame%_%BACKUPDATE%".zip" %dumpbame%_%BACKUPDATE%.log %dumpbame%_%BACKUPDATE%.DMP
::删除10天前的备份。
forfiles /p "%bakdbhome%" /s /m *.zip /d -10 /c "cmd /c del @path"
forfiles /p "%bakdbhome%" /s /m *.log /d -10 /c "cmd /c del @path"
forfiles /p "%bakdbhome%" /s /m *.dmp /d -10 /c "cmd /c del @path"
exit
另外有需要云服务器可以了解下创新互联cdcxhl.cn，海内外云服务器15元起步，三天无理由+7*72小时售后在线，公司持有idc许可证，提供“云服务器、裸金属服务器、高防服务器、香港服务器、美国服务器、虚拟主机、免备案服务器”等云主机租用服务以及企业上云的综合解决方案，具有“安全稳定、简单易用、服务可用性高、性价比高”等特点与优势，专为企业上云打造定制，能够满足用户丰富、多元化的应用场景需求。
本文题目：windows下oracle数据库自动备份bat脚本-创新互联
网页网址：
http://www.cdkjz.cn/article/jicpg.html
